Aapne Excel dokument og lagre som html

[Patton]

Hei,

 

jeg trenger et ganske saa enkelt script som aapner et excel dokument, lagrer dette som html og lukker dokumentet. Noen som kan hjelpe meg paa vei?

Endret 3. mai 2005 av Patton

[aadnk]

Et VB-script med andre ord? I så fall kan du legge inn følgende i en VBS-fil:

 

On Error Resume Next

Const xlHtml = 44
Const xlXMLSpreadsheet = 46

' Hent argumenter
Set Arg = WScript.Arguments

' Dersom ingen fil er blitt spesifisert, må vi be brukeren spesifisere den
If Arg.Count < 1 Then
   sFile = InputBox("Hvilken fil skal konverteres?")
   
   If Len(sFile) = 0 Then
       ' Ikke fortsett - brukeren har klikket på avbryt
       WScript.Quit (1)
   End If
   
Else
   sFile = Arg(0)
End If

' Referer til excel-applikasjonen og åpne den angitte fil
Set Excel = CreateObject("Excel.Application")
Set Workbook = Excel.Workbooks.Open(sFile)

' Ikke fortsett dersom vi hadde problemer med å åpne filen
If Err Then
   WScript.Echo "Kunne ikke åpne fil"
   WScript.Quit (1)
End If

If Arg.Count < 2 Then
   sDestination = InputBox("Hva skal den konverterte filen hete (inkluder hele mappestien)")
Else
   sDestination = Arg(1)
End If

' Ikke fortsett dersom brukeren avbryter dialogboksen
If Len(sDestination) > 0 Then

   ' Lagre filen som HTML
   Workbook.SaveAs sDestination, xlHtml ' Muligens xlXMLSpreadsheet
   
   ' Lukk regnearket
   Workbook.Close
   
   ' Fortell brukeren om resultatet
   If Err Then
       WScript.Echo "Kunne ikke åpne fil"
   Else
       WScript.Echo "Filen er konvertert"
   End If

   ' Rydd opp
   Set Workbook = Nothing
   Set Excel = Nothing
   
End If

[Patton]

Takker og bukker

[Patton]

Et kjapt spoersmaal: I hvordan faar jeg tak kommando-linje argumentene inne i et vbscript?

 

Edit: Glem det, saa nettopp hvordan det blir gjort i eksempelkoden

Endret 3. mai 2005 av Patton

[Patton]

Hvilke endringer maa jeg gjoere for aa lese et excel-dokument i html format og konvertere dette til et vanlig excel-dokument (.xls)?

 

Edit:

Spoersmaal 2: Hva er taste-kombinasjonen for auto-complete i Visual Basic Editor?

Endret 4. mai 2005 av Patton

[aadnk]

Hvilke endringer maa jeg gjoere for aa lese et excel-dokument i html format og konvertere dette til et vanlig excel-dokument (.xls)?

Svært få i bunn og grunn. Alt du behøver, er å legge til følgende øverst i kodefilen:

 

Const xlWorkbookNormal = -4143

 

Hvorpå du endrer den tilsvarende SaveAs-linjen i koden til følgende:

 

  ' Lagre filen som vanlig regneark
  Workbook.SaveAs sDestination, xlWorkbookNormal

 

Jeg er litt usikker på tastekombinasjonen til Autocomplete-funksjonaliteten, men jeg antar det er CTRL + SPACE.

[Patton]

Takker nok en gang