Office i forskjellige versjoner, og snarveier

[Trikrin]

Heisann!

 

På jobb har vi en meny som dukker opp hver gang en bruker logger seg inn.

 

I den menyen finnes det forskjellige snarveier, deriblant Office.

 

Mitt problem er at menyen er felles, men snarveiene til Office er forskjellige, da det er noen som har 2007, noen som har 2003, og faktisk noen som har 2000.

 

Trenger noen gode tips til hvordan jeg skal lage snarveien slik at den passer til alle versjoner av Office. Noen gode ideer?

[enden]

Office har vel hatt standard navn i path siden 2000 - winword, excel, powerpnt, outlook. Resten bruker jeg sjelden, så de kan jeg ikke, men google vet sikkert Kan du bruke disse i menyen?

Endret 7. juli 2009 av enden

[kakkle]

Dersom du har mulighet til å opprette menyen dynamiask, f.eks. ved hjelp av et script, så kan du hente ut hvilken versjon av Office, som er installert ved pålogging, og opprette snarveiene etter hvilken versjon som er installert.

 

Dersom du tildeler skrivebord / start meny ut fra group policy, så må du evt tildele menyer pr gruppe, og samle de som har office 2000, 2003 og 2007 i egne grupper og filtrere på disse.

 

Script som kan opprette snarveier dynamisk:

 

 

Set objWSHShell = CreateObject("WScript.Shell")

strOfficeVersion = getOfficeVersion

strProgDir = objWSHShell.ExpandEnvironmentStrings("%programfiles%") ' som oftest c:\Program Files, men på norsk: C:\Programfiler.

strAllUsersPrograms = objWSHShell.SpecialFolders ("AllUsersPrograms") ' henter ut stien til all users programs (som oftest: c:\Documents And Settings\All Users\Start Menu\Programs (på engelsk))

strOfficeDir = strProgDir & "\Microsoft Office\Office" & strOfficeVersion & "\"

strShortcutLoc = strAllUsersPrograms & "\My Office" ' Hvor skal snarveien plasseres (Her: c:\Documents And Settings\All Users\Start Menu\Programs\My Office)

' Snarvei for Word
addShortcut strShortcutLoc, "Word.lnk", strOfficeDir & "winword.exe", "", strOfficeDir & "winword.exe,0"
' Snarvei for Excel
addShortcut strShortcutLoc, "Excel.lnk", strOfficeDir & "excel.exe", "", strOfficeDir & "excel.exe,0"
' Snarvei for PowerPoint
addShortcut strShortcutLoc, "PowerPoint.lnk", strOfficeDir & "powerpnt.exe", "", strOfficeDir & "powerpnt.exe,0"
' Snarvei for Outlook
addShortcut strShortcutLoc, "Outlook", strOfficeDir & "outlook.exe", "", "" 'strOfficeDir & "Outlook.exe,0"

' Finn office versjon ved å opprette et objekt mot Word, og sjekk versjon på word
' OBS: Merk at dette åpner Word i Bakgrunnen (Word vil ikke vises, men åpnes som en prosess)
'
Function getOfficeVersion()

  Set objWord = CreateObject("Word.Application")
  strVersion = objWord.Version
  objWord.Quit
  arVerParts = Split (strVersion, ".")
  getOfficeVersion = arVerParts(0) ' f.eks. 11 for office 2003, 12 for 2007

End Function

' Legg til snarvei
'
Function addShortcut (strLocation, strName, strTarget, strArg, strIcon)

Set objFSO = CreateObject("Scripting.FilesystemObject")
Set objShell = CreateObject("WScript.shell")
' Sjekk om målfilen finnes, hvis ikke, så ikke lag snarvei
If objFSO.FileExists (strTarget) Then
	' Sjekk om navnet har en "snarvei" endelse (.lnk)
	If Not LCase(Right (strName, 4)) = ".lnk" Then
		strName = strName & ".lnk"
	End If
	' Sjekk om strLocation finnes, hvis ikke, lag mappen
	If Not objFSO.FolderExists (strLocation) Then
		objFSO.CreateFolder strLocation
	End If

	Set objShortCut = objShell.CreateShortcut (strLocation & "\" & strName)
	objShortCut.TargetPath = strTarget
	If strArg <> "" Then
		objShortCut.Arguments = strArg
	End If
	If strIcon <> "" Then
		objShortcut.IconLocation = strIcon
	End If
	objShortcut.WorkingDirectory = strLocation
	objShortcut.Save
End If

End Function

(scriptet er kun testet lokalt på min maskin sånn i full fart nå. Ikke testet ved pålogging.)

 

Det anbefales at scriptet testes grundig i testmiljø før det benyttes i produksjon...

 

Scriptet forutsetter selvfølgelig at du et Office miljø på maskinen (f.eks. dersom du kjører Word 2003 og Outlook 2007, så vil snarveien mot Outlook feile)

 

Det er vel kanskje ikke så veldig gunstig å åpne word hver gang noen logger på, kan gi litt lengre påloggingstid :-(

Ikon argumetentet, er ikke nødvendig å ha med, skal finne standard ikon for applikasjonen selv, men greit dersom man ønsker et annet ikon.

 

Merk at snarveiene opprettes under mappen "My Office". Endre dette til det du vil ha...

 

 

Om du har mulighet til å styre dette med grupper via Group Policy, så er nok det bedre. Det gir kanskje også bedre kontroll over hvilke maskiner som har hvilken office versjon.

 

 

Funksjonen for å hente ut office versjoen er hentet herfra:

http://www.microsoft.com/technet/scriptcen...05/hey0110.mspx

 

EDIT: code tagen ser ikke veldig bra ut i spoiler. Blir veldig smal (ihvertfall hos meg... Mulig de ser bedre ut med et annet tema i forumet)

EDIT2: Så grei ut med dynamisk tema...

 

Forresten, så er kanskje mer elegant å lage et startup script, som kjører når maskinen starter, og lager en system variabel som inneholder stien til Office..., så kan du bare lage snarveiene f.eks. på denne måten:

%officepath%\Winword.exe

%officepath%\excel.exe

%officepath%\powerpnt.exe

%officepath%\Outlook.exe

osv...

Endret 7. juli 2009 av kakkle

[Trikrin]

Najs!

 

Må teste det en gang jeg får anledning. akkurat nå er det "litt" travelt....